Скрипты для Total Commander

  1. Offline

    Andrey_A

    Пользователь

    Posts: 275

    Скрипты - уникальный инструмент для достижения различных целей в работе с файлами и не только, особенно в файловом менеджере, даже если вы раньше об этом ничего не слышали и не знали, то путём простых движений вы можете оптимизировать свои действия
    Тема тестирования скриптов создана для увеличения функциональности Total Commander
    Всё это делается для тех, кто хочет экономить время и автоматизировать работу
    Огромное спасибо участникам, авторам и всем повлиявшим на тему
    #/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#
    В этой теме Каждый может выложить свой скрипт, написанный на любом языке: vbs, js, hta, au3,ahk, bat,cmd... - главное, чтобы он относился как-то к Total Commander, можно было им воспользоваться и к нему было должное описание к применению.
    #/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#
    В теме "Тестирование и заказ скриптов" Каждый может протестировать, дать свой комментарий (все комментарии из этой темы будут удаляться)...если есть интересная идея, вы так же можете поделиться ей в соседней теме и заказать скрипт, а вдруг она покажется интересной для авторов...
    #/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#/#



    Сообщение отредактировал LonerD 25 апреля 2017 - 04:38

    Читайте: Справочные материалы по работе c TC + Онлайн справка TC

    22 ноября 2011 - 13:03 / #1
  2. Offline

    LonerD

    Администратор

    Posts: 614

    '

    Копирование выделенных файлов и папок с добавлением счётчика.


    '================================================================
    ' Copying selected files and folders with addition counter
    ' Копіювання виділених файлів і папок з додаванням лічильника
    ' Копирование выделенных файлов и папок с добавлением счётчика
    '================================================================
    ' Parameters | Параметри | Параметры
    ' 1: filelist | список файлів | список файлов
    ' 2: target directory | каталог призначення | каталог назначения
    ' 3: number of digits that added to the counter
    '    кількість розрядів, що додаються до лічильника
    '    количество разрядов, добавляемых к счётчику
    ' 4: first digit of counter
    '    перша цифра лічильника
    '    первая цифра счётчика
    ' 5: number of copies | число копий | число копій
    '    (if not specified, then entered in dialog)
    '    (якщо не задано, то вводиться в діалозі)
    '    (если не задано, то вводится в диалоге)
    '================================================================
    ' Example | Приклад | Пример : %L %t 3 1 4
    '================================================================
    ' Script:		CopyWithCounterDL.vbs
    ' Author:		LonerD & Andrey Averin & Flasher
    ' Build:		2.05 (2012.08.12)
    '================================================================
    Delim = "_" ' separator
    Cnt = WScript.Arguments.Count
    If Cnt < 2 Then WScript.Quit
    If Cnt > 2 Then : Rank = WScript.Arguments(2) : Else : Rank = 1 : End If
    If Cnt > 3 Then : First = WScript.Arguments(3) : Else : First = 1 : End If
    If Cnt > 4 Then
      Count = WScript.Arguments(4)
      Else
      Count = InputBox("Enter number of copies",_
      "Copying by counter")
    End If
    
    If IsNumeric(Rank) = False Then Rank = 1
    If IsNumeric(First) = False Then First = 1
    If IsNumeric(Count) = False Then Count = 1
    If Rank = 0 Then Rank = 1
    If Count = 0 Then Count = 1
    
    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set ListFile = FSO.OpenTextFile(WScript.Arguments(0), 1)
    Do While Not ListFile.AtEndOfStream
      SelFile = ListFile.ReadLine
      For n=First to Abs(Count)+Abs(First)-1
        Name = FSO.GetBaseName(SelFile) : Ext = FSO.GetExtensionName(SelFile)
          Num = n
          If n < 10^Rank Then Num = Right(String(Rank, "0") & n, Rank)
          FPath = WScript.Arguments(1) & Name & Delim & Num & "." & Ext
        CopyAll
      Next
    Loop
    CreateObject("WScript.Shell").Popup "Happy end. Game over!", 1, "Copying", 64
    ListFile.Close : Set ListFile = Nothing : Set FSO = Nothing : WScript.Quit
    '================================================================
    Sub CopyAll()
      On Error Resume Next
      If FSO.FileExists(SelFile) Then FSO.CopyFile SelFile, FPath
      If FSO.FolderExists(SelFile) Then FSO.CopyFolder Left(SelFile, Len(SelFile) - 1), FPath
    End Sub
    '================================================================
    
    30 марта 2013 - 19:52 / #151
  3. Offline

    Andrey_A

    Пользователь

    Posts: 275

    ИМХО лучше внести

      Count = InputBox("Enter number of copies","Copying by counter")
      If IsEmpty(Count) Then WScript.Quit



    если человек ошибся - и нажимает кнопку отмена.

    Читайте: Справочные материалы по работе c TC + Онлайн справка TC

    30 марта 2013 - 21:39 / #152

Статистика форума, пользователей онлайн: 0 (за последние 30 минут)

---
Создано тем
107
Всего сообщений
4048
Пользователей
99000
Новый участник
termojader